TMAKE Reference Manual

Project Tags

TMAKE recognizes several project tags. The syntax for setting a project variable is:

    TAG = value

TMAKE can also do tag expansion using $$:

    ALLFILES = Project files: $$HEADERS $$SOURCES

Normally you assign to a tag, but you can also add to a tag, subtract from a tag or replace parts of the tag.

    A   = abc
    X   = xyz
    A  += def			# A = abc def
    X  *= xyz			# X = xyz
    B   = $$A			# B = abc def
    B  -= abc			# B = def
    X  /= s/y/Y/		# X = xYz

The *= operation adds the value if the tag does not already contain it. The /= operation performs regular expression substitution.

You can also set tags from the command line when running the tmake program. For instance, if you want to generate a makefile with debug information:

    tmake hello.pro "CONFIG+=debug"

Use the unix: or win32: qualifier if you want a platform-specific tag:

    SOURCES	   =   common.cpp   # common for all platforms
    unix:SOURCES   +=  unix.cpp	    # additional sources for UNIX
    win32:SOURCES  +=  win32.cpp    # additional sources for Windows
    unix:LIBS	   +=  -lm	    # on UNIX we need the math lib

You may even define your own project tags to be used by custom templates. A project tag is stored in %project, which is an associative Perl array. Access it like this: $project{"tag"}. For example, after reading "hello.pro", $project{"SOURCES"} contains "hello.cpp main.cpp".

Project Tag Reference

ALL_DEPS

Specifies additional dependencies for the makefile target "all:".

CLEAN_FILES

Specifies additional files to be removed for "make clean".

Example:

  CLEAN_FILES = core *~

CONFIG

Sets the make configuration. It tells the TMAKE templates what compiler options to use and which extra libraries to link in.

debug Compile with debug options enabled.

dll Create a DLL/shared object target (app.t only).

opengl This is an application which requires the OpenGL library.

qt This is a Qt application. Tells tmake to add rules for moc files and link with the Qt library.

release Compile with optimization enabled. This option is ignored if "debug" is specified.

staticlib UNIX/lib.t only: Create only a static library, no shared library.

warn_on The compiler should emit more warnings than normally. This option is ignored if "warn_off" is specified.

warn_off The compiler should emit no warnings or as few as possible.

windows Windows only: The application requires Windows header files and the Windows libraries.

x11 X11 only: The application requires X header files and the libX11 library.

DEF_FILE

Win32/app.t only: Specifies a .def file.

DESTDIR

Specifies where to put the target file. Example:

  DESTDIR = ../../lib

You must create this directory before running make.

FILETAGS

Tells TMAKE which tags contain file names. This is because TMAKE on Windows replace the directory separator / with \.

HEADERS

Defines the header files of the project.

INCPATH

This tag is generated from INCLUDEPATH. The ';' or ':' separators have been replaced by ' ' (single space). This makes it easier to split. qtapp.t and other templates expand INCPATH to set -I options for the C++ compiler.

INCLUDEPATH

This tag specifies the #include directories. It can be set in the project file, or by the AddIncludePath() function.

Example:

  INCLUDEPATH = c:\msdev\include;d:\stl\include

Use ';' as the directory separator.

LIBS

Defines additional libraries to be linked in when creating an application or a shared library. You probably want to use a platform qualifier since libraries are specified differently on UNIX and Win32.

Example:

  unix:LIBS  = -lXext -lm
  win32:LIBS = ole32.lib

MOC_DIR

Specifies where to put the temporary moc output files. By default they are stored in the directory where the moc input files are.

Example:

  MOC_DIR = tmp

You must create this directory before running make.

OBJECTS

This tag is generated from SOURCES by the StdInit() function. The extension of each source file has been replaced by .o (UNIX) or .obj (Win32).

Example:

  SOURCES = a.x b.y

Then OBJECTS become "a.o b.o" on UNIX and "a.obj b.obj" on Win32.

OBJECTS_DIR

Specifies where to put object files. By default they are stored in the directory where the source files are.

Example:

  OBJECTS_DIR = tmp

You must create this directory before running make.

OBJMOC

This tag is generated by the StdInit() function if $moc_aware is true. OBJMOC contains the name of all intermediate moc object files.

Example:

  HEADERS = demo.h
  SOURCES = demo.cpp main.cpp

If demo.h and main.cpp define classes that use signals and slots (i.e. the Q_OBJECT "keyword" is found in these two files), OBJMOC becomes:

  OBJMOC  = moc_demo.obj

PROJECT

This is the name of the project. It defaults to the name of the project file, excluding the .pro extension.

RC_FILE

Win32/app.t only: Specifies a .rc file. Cannot be used with the RES_FILE tag.

RES_FILE

Win32/app.t only: Specifies a .res file. You can either specify a .rc file or one or more .res files.

SOURCES

Defines the source files of the project.

SRCMOC

This tag is generated by the StdInit() function if CONFIG contains "qt". SRCMOC contains the name of all intermediate moc files.

Example:

  HEADERS = demo.h
  SOURCES = demo.cpp main.cpp

If demo.h and main.cpp define classes that use signals and slots (i.e. the Q_OBJECT "keyword" is found in these two files), SRCMOC becomes:

  SRCMOC  = moc_demo.cpp main.moc

TARGET

Sets the makefile target, i.e. what program to build.

TEMPLATE

Sets the default template. This can be overridden by the tmake -t option.

Function Reference

This section contains a brief description of some important tmake functions used by the templates.

AddIncludePath(path)

Adds path to the include path variable, INCLUDEPATH. The include path is used for two purposes:

Searching files when generating include dependencies.
Setting -I options for the C/C++ compiler.

Example:

  #$ AddIncludePath('$QTDIR/include;/local/include');

BuildMocObj(objects,sources)

Creates build rules for moc source files. Generates include dependencies.

Example:

  #$ BuildMocObj($project{"OBJMOC"},$project{"SRCMOC"});

Output:

  moc_hello.o: moc_hello.cpp \
		hello.h \
		...

BuildMocSrc(files)

Creates moc source files from C++ files containing classes that define signals and slots. For a header file x.h, the generated moc file is called moc_x.h. For a source file y.cpp, the generates moc file is called y.moc and should be #include'd by y.cpp.

Example:

  #$ BuildMocSrc($project{"HEADERS"});
  #$ BuildMocSrc($project{"SOURCES"});

Output:

  moc_hello.cpp: hello.h
	$(MOC) hello.h -o moc_hello.cpp

BuildObj(objects,sources)

Creates build rules for source files. Generates include dependencies.

Example:

  #$ BuildObj($project{"OBJECTS"},$project{"SOURCES"});

Output:

  hello.o: hello.cpp \
		hello.h \
		...

  main.o: main.cpp \
		hello.h \
		...

Config(string)

Returns true if the CONFIG tag contains the given string.

Example:

  #$ if ( Config("release") { }

DisableOutput()

Call this function to force TMAKE to generate no output until EnableOutput() is called.

Example:

  #$ Config("debug") && DisableOutput();
      Anything here is skipped if CONFIG contains "debug".
  #$ Config("debug") && EnableOutput();

EnableOutput()

Enables TMAKE output after DisableOutput() was called.

Expand(tag)

Expands a project tag. Equivalent to $text = $project{$tag}.

Example:

  VERSION = #$ &expand("VERSION");

Output:

  VERSION = 1.1

ExpandGlue(tag,prepend,glue,append)

Expands a $project{} tag, splits on whitespace and joins with $glue. $prepend is put at the start of the string and $append is put at the end of the string. The resulting string ($text) becomes "" if the project tag is empty or not defined.

Example:

  clear:
          #$ ExpandGlue("OBJECTS","-del","\n\t-del ","");

Output (Windows NT):

  clear:
          -del hello.obj
          -del main.obj

ExpandList(tag)

This function is suitable for expanding lists of files. Equivalent with ExpandGlue($tag,""," \\\n\t\t","").

Example:

  OBJECTS = #$ ExpandList("OBJECTS");

Output:

  OBJECTS = hello.o \
	    main.o

IncludeTemplate(file)

Includes a template file. The ".t" extension is optional.

Example:

  #$ IncludeTemplate("qtapp");

Now()

Sets $text to the current date and time.

Example:

  # Generated at #$ Now()

Output:

  # Generated at 12:58, 1996/11/19

Project(strings)

This is a powerful function for setting and reading project variables. Returns the resulting project variables (joined with space between).

Examples:

# Get a project variable:
    $s = Project("TEMPLATE");	    -> $s = "TEMPLATE"

# Set a project variable:
    Project("TEMPLATE = lib");	    -> TEMPLATE = lib
    Project("CONFIG =";)	    -> CONFIG empty

# Append to a project variable:
    Project("CONFIG = qt");	    -> CONFIG = qt
    Project("CONFIG += debug");	    -> CONFIG = qt debug

# Append to a project variable if it does not contain the value already:
    Project("CONFIG = qt release"); -> CONFIG = qt release
    Project("CONFIG *= qt");	    -> CONFIG = qt release
    Project("CONFIG *= opengl");    -> CONFIG = qt release opengl

# Subtract from a project variable:
    Project("THINGS = abc xyz");    -> THINGS = abc xyz
    Project("THINGS -= abc");	    -> THINGS = xyz

# Search/replace on a project variable:
    Project("CONFIG = tq opengl");  -> CONFIG = tq opengl
    Project("CONFIG /= s/tq/qt/");  -> CONFIG = qt opengl

# The operations can be performed on several project variables at a time.

    Project("TEMPLATE = app", "CONFIG *= opengl", "THINGS += klm");

ScanProject(file)

Scans a project file and stores the project tags and values in the global associative %project array.

StdInit()

Standard initialization of tmake. StdInit() should be called from one of the first lines in the template.

This function creates some new project tags:

OBJECTS - Object files corresponding to SOURCES.
SRCMOC - moc source files.
OBJMOC - moc object files.

The moc-related tags are created only if CONFIG contains "qt"

Substitute(string)

This function takes a string and substitutes any occurrence of $$tag with the actual content of the tag. Returns the substituted string. Also sets $text.

Important: Use single quotes around the string, otherwise perl will expand any $tags it finds.

Example:

    Substitute('Project name: $$PROJECT, uses template $$TEMPLATE');

	debug		Compile with debug options enabled.
	dll		Create a DLL/shared object target (app.t only).
	opengl		This is an application which requires the OpenGL library.
	qt		This is a Qt application. Tells tmake to add rules for moc files and link with the Qt library.
	release		Compile with optimization enabled. This option is ignored if "debug" is specified.
	staticlib		UNIX/lib.t only: Create only a static library, no shared library.
	warn_on		The compiler should emit more warnings than normally. This option is ignored if "warn_off" is specified.
	warn_off		The compiler should emit no warnings or as few as possible.
	windows		Windows only: The application requires Windows header files and the Windows libraries.
	x11		X11 only: The application requires X header files and the libX11 library.